这是111.dat里的内容，我看不懂
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns:dcterms="http://purl.org/dc/terms/"
xmlns:rss="http://purl.org/rss/1.0/"
xmlns:rss09="http://my.netscape.com/rdf/simple/0.9/"
xmlns:content="http://purl.org/rss/1.0/modules/content/"
xmlns:annotate="http://purl.org/rss/1.0/modules/annotate/"
xmlns:admin="http://webns.net/mvcb/"
xmlns:image="http://purl.org/rss/1.0/modules/image/"
xmlns:l="http://purl.org/rss/1.0/modules/link"
xmlns:cc="http://web.resource.org/cc/"
xmlns:reqv="http://purl.org/rss/1.0/modules/richequiv/"
xmlns:slash="http://purl.org/rss/1.0/modules/slash/"
xmlns:syn="http://purl.org/rss/1.0/modules/syndication/"
xmlns:feed="http://purl.org/atom/ns#"
xmlns:mrx="http://www.maxthon.com/docs/RssExtension/"
exclude-result-prefixes="mrx rdf dc feed dcterms rss rss09 content annotate admin image cc reqv slash syn l"
version="1.0">
<xsl:output indent="yes" method="xml" encoding="utf-8" omit-xml-declaration="yes" cdata-section-elements="description title"/>
<xsl:preserve-space elements="*"/>
<!-- Main Content -->
<xsl:template match="/">
<feed>
<xsl:apply-templates select="/rss"/>
<xsl:apply-templates select="/rdf:RDF"/>
<xsl:apply-templates select="/feed:feed"/>
</feed>
</xsl:template>
<!-- RSS 2.0 -->
<xsl:template match="/rss">
<title><xsl:value-of select="//channel/title" /></title>
<link><xsl:value-of select="//channel/link" /></link>
<type>RSS 2.0</type>
<language><xsl:value-of select="//channel/dc:language" /><xsl:value-of select="//channel/language" /></language>
<xsl:apply-templates select="channel/item"/>
</xsl:template>
<xsl:template match="channel/item">
<xsl:call-template name="item">
<xsl:with-param name="title" select="title"/>
<xsl:with-param name="link" select="link"/>
<xsl:with-param name="description" select="description"/>
<xsl:with-param name="author" select="author"/>
<xsl:with-param name="date" select="pubDate"/>
<xsl:with-param name="importance" select="mrx:importance"/>
<xsl:with-param name="rating" select="mrx:rating"/>
<xsl:with-param name="audio" select="enclosure[contains(@type,'audio/')]/@url"/>
<xsl:with-param name="video" select="enclosure[contains(@type,'video/')]/@url"/>
</xsl:call-template>
</xsl:template>
<!-- RSS 1.0 -->
<xsl:template match="/rdf:RDF">
<title><xsl:value-of select="//*[name()='title']" /></title>
<link><xsl:value-of select="//*[name()='link']" /></link>
<type>RSS 1.0</type>
<language><xsl:value-of select="*/dc:language" /></language>
<xsl:apply-templates select="rss:item"/>
<xsl:apply-templates select="rss09:item"/>
</xsl:template>
<xsl:template match="rss:item">
<xsl:call-template name="item">
<xsl:with-param name="title" select="rss:title"/>
<xsl:with-param name="link" select="rss:link"/>
<xsl:with-param name="description" select="rss:description"/>
<xsl:with-param name="author" select="dc:creator"/>
<xsl:with-param name="date" select="dc:date"/>
</xsl:call-template>
</xsl:template>
<xsl:template match="rss09:item">
<xsl:call-template name="item">
<xsl:with-param name="title" select="rss09:title"/>
<xsl:with-param name="link" select="rss09:link"/>
<xsl:with-param name="description" select="rss09:description"/>
</xsl:call-template>
</xsl:template>
<!-- Atom 0.3 -->
<xsl:template match="/feed:feed">
<title><xsl:value-of select="feed:title" /></title>
<link><xsl:value-of select="feed:link[@rel='alternate' and @type='text/html']/@href" /></link>
<type>Atom 0.3</type>
<language><xsl:value-of select="/feed:feed/@xml:lang" /></language>
<xsl:apply-templates select="feed:entry"/>
</xsl:template>
<xsl:template match="feed:entry">
<xsl:call-template name="item">
<xsl:with-param name="title" select="feed:title"/>
<xsl:with-param name="link" select="feed:link[@rel='alternate' and @type='text/html']/@href"/>
<xsl:with-param name="description" select="feed:summary"/>
<xsl:with-param name="content" select="feed:content"/>
<xsl:with-param name="author" select="feed:author/feed:name"/>
<xsl:with-param name="date" select="feed:created"/>
</xsl:call-template>
</xsl:template>
<!-- Output Items For all Feeds -->
<xsl:template name="item">
<xsl:param name="title"/>
<xsl:param name="link"/>
<xsl:param name="author"/>
<xsl:param name="date"/>
<xsl:param name="description" select="''"/>
<xsl:param name="content" select="''"/>
<xsl:param name="importance"/>
<xsl:param name="rating"/>
<xsl:param name="audio"/>
<xsl:param name="video"/>
<item>
<id><xsl:value-of select="generate-id($title)"/></id>
<title><xsl:value-of select="translate($title,'
','')" disable-output-escaping="yes"/></title>
<link><xsl:value-of select="translate($link,'
','')"/></link>
<author><xsl:value-of select="translate($author,'
','')"/></author>
<date><xsl:value-of select="translate($date,'
','')"/></date>
<description>
<xsl:choose>
<xsl:when test="$description">
<xsl:value-of select="$description" disable-output-escaping="yes" />
</xsl:when>
<xsl:when test="$content">
<xsl:value-of select="$content" disable-output-escaping="yes" />
</xsl:when>
</xsl:choose>
</description>
<importance><xsl:value-of select="$importance"/></importance>
<rating><xsl:value-of select="$rating"/></rating>
<audio><xsl:value-of select="$audio"/></audio>
<video><xsl:value-of select="$video"/></video>
</item>
</xsl:template>
</xsl:stylesheet>
222.dat
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
exclude-result-prefixes="xsl"
version="1.0">
<xsl:output indent="yes" encoding="utf-8" method="html" omit-xml-declaration="yes" />
<xsl:template match="/feed">
<html>
<head>
<title><xsl:value-of select="title"/></title>
<link rel="stylesheet" href="style.css" type="text/css" media="screen" />
</head>
<body>
<div id="header"><a href="{link}" target="_blank"><h1><xsl:value-of select="title"/></h1></a></div>
<div id="list"><ul><xsl:apply-templates select="item" mode="list"/></ul></div>
<div id="content"><xsl:apply-templates select="item" mode="content"/></div>
</body>
</html>
</xsl:template>
<xsl:template match="item" mode="content">
<div class="textbox">
<a name="{id}" />
<div class="title">
<h3><a href="{link}" target="_blank"><xsl:value-of select="title"/></a></h3>
<div class="label"><xsl:if test="author!=''"><xsl:value-of select="author"/> | </xsl:if><xsl:value-of select="date"/></div>
</div>
<div class="content"><xsl:value-of select="description" disable-output-escaping="yes" /></div>
<div class="go-top"><a href="#">Top</a></div>
</div>
<br />
</xsl:template>
<xsl:template match="item" mode="list">
<li><a href="#{id}" title="{title}"><xsl:value-of select="title"/></a></li>
</xsl:template>
</xsl:stylesheet>
333.dat
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
exclude-result-prefixes="xsl"
version="1.0">
<xsl:output indent="no" encoding="utf-8" method="text" omit-xml-declaration="yes"/>
<xsl:template match="/feed">
[Descriptions]($br$)
FeedTitle=<xsl:value-of select="title"/>($br$)
<xsl:apply-templates select="item"/>
</xsl:template>
<xsl:template match="item">
<xsl:value-of select="id"/>=<xsl:value-of select="title"/>($br$)
<xsl:value-of select="id"/>*->URL=<xsl:value-of select="link"/>($br$)
<xsl:value-of select="id"/>*->Des=<xsl:value-of select="description" disable-output-escaping="yes"/>($br$)
<xsl:value-of select="id"/>*->Date=<xsl:value-of select="date"/>($br$)
<xsl:value-of select="id"/>*->Importance=<xsl:value-of select="importance"/>($br$)
<xsl:value-of select="id"/>*->Rating=<xsl:value-of select="rating"/>($br$)
<xsl:value-of select="id"/>*->Audio=<xsl:value-of select="audio"/>($br$)
<xsl:value-of select="id"/>*->Video=<xsl:value-of select="video"/>($br$)
</xsl:template>
</xsl:stylesheet>
